***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 29, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZ1AH5V6B-AU A K
.param
+vc0 = 7.372e-11		vc1 = 1.327e-10		vc2 = 5.267e-11		vc3 = {3.404-1e-4*(temp-25)}
+tc1 = 1.062e-2		tc2 = 2.531e-2		tc3 = 5.222e-3		tc4 = 5.034e-3
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A)**2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(K,A)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 8.107e-15		   n = 1.002		  rs = 1.784e-2		ikf = 2.036
+ibv = 100e-3		 nbv = 1			  bv = 5.6
***** capacitance parameter ***
+cjo = 1.002e-9		   m = 4.969e-1		  vj = 1.407e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25			  eg = 1.108		 xti = 3
+trs1 = 1e-4		tbv1 = 2.782e-4
.ends PZ1AH5V6B-AU
*$
